IssueTracker

If I am setting Java toolchain via extension:

java {
    toolchain {
        languageVersion.set(JavaLanguageVersion.of(15))
    }
}

JavaCompile tasks created by AGP are still using current Gradle daemon JDK and not configured toolchain one.

It is possible to workaround by explicitly setting toolchain for all JavaCompile tasks:

tasks.withType(JavaCompile).configureEach {
    javaCompiler = javaToolchains.compilerFor {
        languageVersion = JavaLanguageVersion.of(15)
    }
}

Version of Gradle Plugin: 7.0.0-beta05 Version of Gradle: 7.1.1 Version of Java: 11.0.11 OS: Linux

Steps to Reproduce:

1. Create a new project with following app/build.gradle file:

plugins {
    id 'com.android.application'
    id 'kotlin-android'
}

java {
    toolchain {
        languageVersion.set(JavaLanguageVersion.of(15))
    }
}

android {
    compileSdkVersion 30

    defaultConfig {
        applicationId "com.example.myapplication"
        minSdkVersion 30
        targetSdkVersion 30
        versionCode 1
        versionName "1.0"

        testInstrumentationRunner "androidx.test.runner.AndroidJUnitRunner"
    }

    buildTypes {
        release {
            minifyEnabled false
            proguardFiles getDefaultProguardFile('proguard-android-optimize.txt'), 'proguard-rules.pro'
        }
    }
    compileOptions {
        sourceCompatibility JavaVersion.VERSION_1_8
        targetCompatibility JavaVersion.VERSION_1_8
    }

    kotlinOptions {
        jvmTarget = '1.8'
    }
}

dependencies {

    implementation "org.jetbrains.kotlin:kotlin-stdlib:$kotlin_version"
    implementation 'androidx.core:core-ktx:1.3.1'
    implementation 'androidx.appcompat:appcompat:1.3.0'
    implementation 'com.google.android.material:material:1.2.1'
    implementation 'androidx.constraintlayout:constraintlayout:2.0.1'
    testImplementation 'junit:junit:4.+'
    androidTestImplementation 'androidx.test.ext:junit:1.1.3'
    androidTestImplementation 'androidx.test.espresso:espresso-core:3.4.0'
}

2. Run ./gradlew :app:assembleDebug -i using JDK 11 and check task :app:compileDebugWithJavac logs for line Compiling with toolchain - it should point to the configured toolchain JDK 15 and not current Gradle daemon JDK 11.